Регистрийн дугаараас төрсөн огноо, насыг яаж олох вэ?

Энэ нийтлэлээр өгөгдсөн регистрийн дугаараас төрсөн жил, сар, өдрийг ялгаж, насыг хэрхэн тооцохыг үзье.

Регистрийн дугаарын хувьд 2000 оноос хойш төрсөн хүүхдийн сар дээр 20-г нэмдэг тул үүнийг мөн томъёо бичихдээ бодолцох ёстой.

Асуулт: Регистрийн дугаараас насыг олох томъёо хэрхэн бичих вэ?

Шийдэл

Эхлээд регистрийн дугаараас төрсөн жилийг олох томъёо бичье. Ингэхдээ IF болон MID томъёог хослуулж ашиглана. Томъёоны тайлбар нь хэрвээ тухайн регистрийн дугаарын 5 болон 6 дахь орон буюу сар нь 20-с их бол 2000 оноос хойш төрсөн, 20-с бага 2000 оноос өмнө төрсөн болно. 20-с их бол MID(A2,3,2) буюу 3, 4 дэхь орон дээр 2000-г нэмнэ, 20-с бага бол 1900-г нэмж төрсөн жилийг олно.

=IF(MID(A2,5,2)>"20",MID(A2,3,2)+2000,MID(A2,3,2)+1900)

Үр дүн:
1986

Төрсөн сарыг дараах томъёогоор олно. Сарыг олоход 2000 оноос хойш төрсөн хүүхдийн нас дээр 20-г нэмдэг тул уг нөхцлийг бодохын тулд IF болон MID томъёог дараах байдлаар хослуулж бичнэ.

=IF(MID(A2,5,2)>"20",MID(A2,5,2)-"20",MID(A2,5,2)-"0")

Үр дүн:
4

Төрсөн өдөр олох. Төрсөн өдрийг олохдоо MID томъёо ашиглана.

=MID(A2,7,2)

Үр дүн:
23

Төрсөн жил, сар, өдрийн ашиглан огноо формат үүсгэхдээ DATE томъёо ашиглан огноо үүсгэнэ.

=DATE(B2,C2,D2)

Үр дүн:
23/4/1986

Yearfrac томъёо ашиглаж өнөөдрийн огнооноос төрсөн оныг хасч насыг олно. Ингэхдээ насыг бүхлээр харуулах тул Round хийнэ.

=ROUND(YEARFRAC(E2,TODAY()),0)

Үр дүн:
38

Дээрх томъёонуудыг нэгтгэн G2 нүдэнд дараах байдлаар бичиж болно:

=ROUND(YEARFRAC(DATE(IF(MID(A2,5,2)>"20",MID(A2,3,2)+2000,MID(A2,3,2)+1900),IF(MID(A2,5,2)>"20",MID(A2,5,2)-"20",MID(A2,5,2)-"0"),MID(A2,7,2)),TODAY()),0)

Бичсэн томъёогоо доош хуулж регистрийн дугаар тус бүрийн хувьд насыг олно. Үр дүн дараах байдалтай гарч ирнэ.